home *** CD-ROM | disk | FTP | other *** search
/ Mac Magazin/MacEasy 32 / Mac Magazin and MacEasy Magazine CD - Issue 32.iso / Grafik & Text / OzTeX3.0 / Metafont / Inputs / ec / exrueast.mf < prev    next >
Text File  |  1997-03-16  |  45KB  |  992 lines
  1. % exrueast.mf
  2. %
  3. % (c) Copyright 1995, 1996, 1997 J"org Knappen
  4. % (c) Copyright 1990, 1992 Norbert Schwarz
  5. %
  6. % This file is part of ecfonts version 1.0
  7. %
  8. % Please read the files 00readme.txt, 00inst.txt, 00error.txt, and
  9. % copyrite.txt for further information
  10. %
  11. % You find some documentation in ecdoc.tex (needs LaTeX2e)
  12. %
  13. % Content:
  14. %
  15. %   uppercase accented letters (common to roman and italic fonts)
  16. %   "eastern part"
  17. %
  18. %   oct"200" .. oct"235"
  19. %
  20. %   Roman uppercase accents
  21. %
  22. %       oct"200"    A  with breve
  23. %       oct"201"    A  with ogonek
  24. %       oct"202"    C  with acute
  25. %       oct"203"    C  with hachek
  26. %       oct"204"    D  with hachek
  27. %       oct"205"    E  with hachek
  28. %       oct"206"    E  with ogonek
  29. %       oct"207"    G  with breve
  30. %
  31. %       oct"210"    L  with acute
  32. %       oct"211"    L  with komma
  33. %       oct"212"    L  with stroke (polish)
  34. %       oct"213"    N  with acute
  35. %       oct"214"    N  with hachek
  36. %       oct"215"    The letter Eng
  37. %       oct"216"    O  with hungarian umlaut
  38. %       oct"217"    R  with acute
  39. %
  40. %       oct"220"    R  with hachek
  41. %       oct"221"    S  with acute
  42. %       oct"222"    S  with hachek
  43. %       oct"223"    S  with cedilla
  44. %       oct"224"    T  with hachek
  45. %       oct"225"    T  with cedilla
  46. %       oct"226"    U  with hungarian umlaut
  47. %       oct"227"    U  with ring
  48. %
  49. %       oct"230"    Y  with umlauts
  50. %       oct"231"    Z  with acute
  51. %       oct"232"    Z  with hachek
  52. %       oct"233"    Z  with dot
  53. %       oct"234"    IJ
  54. %       oct"235"    I  with dot
  55.  
  56. version_check(1,0);  % |version_check| was introduced in dc1.3
  57.  
  58. ecchar "The letter A with breve";
  59. beginchar(oct"200",13u#,cap_height#+acc_height#,0);
  60. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  61. numeric left_stem,right_stem,outer_jut,alpha;
  62. right_stem=cap_stem-stem_corr;
  63. left_stem=min(cap_hair if hefty: -3stem_corr fi,right_stem);
  64. outer_jut=.8cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
  65. x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=cap_height+apex_o+apex_oo;
  66. alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  67. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  68. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  69. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  70. if y0<cap_height-cap_notch_cut: y0:=cap_height-cap_notch_cut;
  71.  fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  72.   --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  73.   ...{up}z0+.5left--cycle; % left and right diagonals
  74. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  75.   --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  76. penpos5(whatever,angle(z2-z1)); z5=whatever[z1,z2];
  77. penpos6(whatever,angle(z3-z4)); z6=whatever[z3,z4]; y6=y5;
  78. if hefty: y5r else: y5 fi =5/12y0;
  79. y5r-y5l=y6r-y6l=cap_band; penstroke z5e--z6e; % bar line
  80. if serifs: numeric inner_jut; pickup tiny.nib;
  81.  prime_points_inside(1,2); prime_points_inside(4,3);
  82.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  83.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  84.  dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark);  % left serif
  85.  dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi  % right serif
  86. % the accent
  87. uppercase_breve(x2,0,12,13,14);
  88. penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
  89.  
  90.  
  91. %%% fine fisp
  92. ecchar "The letter A with ogonek"; % from pl_dl (plfonts)
  93. beginchar(oct"201",13u#,cap_height#,the_ogonek_depth#);
  94.  adjust_fit(cap_serif_fit#,cap_serif_fit#);
  95.  numeric left_stem,right_stem,outer_jut,alpha;
  96.  right_stem=cap_stem-stem_corr;
  97.  left_stem=min(cap_hair if hefty: -3stem_corr fi,right_stem);
  98.  outer_jut=.8cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
  99.  x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
  100.  alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  101.  penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  102.  penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  103.  z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  104.  if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  105.   fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  106.    --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  107.    ...{up}z0+.5left--cycle; % left and right diagonals
  108.  else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  109.    --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  110.  penpos5(whatever,angle(z2-z1)); z5=whatever[z1,z2];
  111.  penpos6(whatever,angle(z3-z4)); z6=whatever[z3,z4]; y6=y5;
  112.  if hefty: y5r else: y5 fi =5/12y0;
  113.  y5r-y5l=y6r-y6l=cap_band; penstroke z5e--z6e; % bar line
  114.  if serifs: numeric inner_jut; pickup tiny.nib;
  115.   prime_points_inside(1,2); prime_points_inside(4,3);
  116.   if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  117.   else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  118.   dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark); % left serif
  119.   dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi % right serif
  120.  penlabels(0,1,2,3,4,5,6);
  121.  def the_pen=if known ogonek_pen: ogonek_pen
  122.   elseif serifs: tiny elseif is_bold: fisp else: fine fi
  123.  enddef;
  124.  ogonek_breadth=if serifs and is_bold: slab else: xvair fi;
  125. % |diag_end| refers to |tiny| pen, hence |tiny| in the following equation:
  126.  ogonek_pos=(x4 if not serifs: l if is_bold: +.75tiny fi\\ fi,.5the_pen)
  127.    if serifs and not is_egyptian: +(.5xvair,0) fi;
  128.  put_ogonek(the_pen);
  129. endchar;
  130.  
  131. ecchar "The letter C with acute"; % from pl_dl (plfonts)
  132. if serifs:
  133.  beginchar_twice(oct"202",13u#,cap_height#,0);
  134.  italcorr cap_height#*slant-.5u#;
  135.  adjust_fit(0,0);
  136.  pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
  137.  pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
  138.  rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
  139.  top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
  140.  bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
  141.  y5=max(good.y .95(h-y1),y4l+eps);
  142.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  143.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  144.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  145.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
  146.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
  147.  x1r-x1'=2cap_curve-fine; y1'=y1;
  148.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  149.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  150.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  151.  penlabels(1,1',2,3,4,5,6);
  152.  put_accent;
  153.  repeat_once;
  154. else: beginchar_twice(oct"202",11.5u#,cap_height#,0);
  155.  italcorr cap_height#*slant-.5u#;
  156.  adjust_fit(0,0);
  157.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  158.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
  159.  rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
  160.  lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
  161.  top y1r=vround .95h+o; top y2r=h+o; y3=.5h;
  162.  bot y4r=-o; bot y5r=vround .08h-o; y5l:=good.y y5l; x5l:=good.x x5l;
  163.  filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
  164.   & super_arc.e(3,4) & term.e(4,5,right,.8,4); % arc and terminals
  165.  penlabels(1,1',2,3,4,5,6);
  166.  put_accent;
  167.  repeat_once;
  168. fi
  169. endchar; 
  170.  
  171. ecchar "The letter C with hachek"; % from cshacheu.mf (csfonts)
  172. if serifs: beginchar(oct"203",13u#,cap_height#+acc_height#,0);
  173.  italcorr cap_height#*slant-.5u#;
  174.  adjust_fit(0,0);
  175.  pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
  176.  pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
  177.  rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
  178.  top y2r=cap_height+o; bot y4r=-o; y3=.5[y2,y4];
  179.  bot y1=min(vround max(.6cap_height,x_height-.5vair),bot y2l-eps);
  180.  y5=max(good.y .95(cap_height-y1),y4l+eps);
  181.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  182.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  183.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  184.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
  185.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=cap_height+o;
  186.  x1r-x1'=2cap_curve-fine; y1'=y1;
  187.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  188.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  189.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  190. else: beginchar(oct"203",11.5u#,cap_height#+acc_height#,0);
  191.  italcorr cap_height#*slant-.5u#;
  192.  adjust_fit(0,0);
  193.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  194.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
  195.  rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
  196.  lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
  197.  top y1r=vround .95cap_height+o; top y2r=cap_height+o; y3=.5cap_height;
  198.  bot y4r=-o; bot y5r=vround .08cap_height-o; y5l:=good.y y5l; x5l:=good.x x5l;
  199.  filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
  200.   & super_arc.e(3,4) & term.e(4,5,right,.8,4); fi % arc and terminals
  201. math_fit(-.3cap_height#*slant-.5u#,.5ic#);
  202. penlabels(1,1',2,3,4,5,6);
  203. uc_hachek_accent(x2l);
  204. %uc_hachek_accent(0.6[x3,x1]);    %% changed from .5 to .65  % 25/12/91
  205. endchar;             %% and to .6  % 3/1/92 %% changed via lc  11/3/92
  206.  
  207.  
  208. ecchar "The letter D with hachek"; % from cshacheu.mf (csfonts)
  209. beginchar(oct"204",13.5u#,cap_height#+acc_height#,0);
  210. italcorr .7cap_height#*slant-.5u#;
  211. adjust_fit(cap_serif_fit#,0);
  212. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  213. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem');
  214. top y1=cap_height; bot y2=0;
  215. filldraw stroke z1e--z2e; % stem
  216. penpos3(cap_band,90); penpos4(cap_band,90);
  217. penpos5(cap_curve-stem_corr,0);
  218. penpos6(cap_band,-90); penpos7(cap_band,-90);
  219. z3r=top z1; y4=y3; y5=.51[y4,y6]; y6=y7;
  220. z7r=bot z2; x4=x6=.5w+.25u; x5r=hround(w-u);
  221. x4l:=x6l:=x4-.25cap_curve;
  222. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  223. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  224.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  225. math_fit(0,ic#-.5u#); penlabels(1,2,3,4,5,6,7);
  226. uc_hachek_accent(1/3[x1l,x5r]);
  227. endchar;
  228.  
  229.  
  230. ecchar "The letter E with hachek"; % from cshacheu.mf (csfonts)
  231. beginchar(oct"205", 12u#-width_adj#,cap_height#+acc_height#,0);
  232. italcorr cap_height#*slant-beak_jut#-.5u#;
  233. adjust_fit(cap_serif_fit#,0);
  234. hh:=vround(cap_height-stem_corr);
  235. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  236. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=hh; bot y2=0;
  237. filldraw stroke z1e--z2e; % stem
  238. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  239. top y3r=hh; x3=x1; rt x4r=hround(w-u); y4=good.y(y3l-beak)-eps;
  240. arm(3,4,e,beak_darkness,beak_jut);  % upper arm and beak
  241. pos5(cap_bar,-90); pos6(hair,0);
  242. top y5l=vround(.52[y2,y1]+.5cap_bar); x5=x1;
  243. pos0(cap_bar,90); pos7(hair,0);
  244. z0=z5; x6=x7; y6-y5l=y0l-y7;
  245. if serifs: rt x6r=hround(w-4.4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  246.  rt x9r=hround(w-.5u);
  247. else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  248. arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0);  % middle arm and serif
  249. pos8(slab if not serifs:+2stem_corr fi,-90); pos9(hair,0);
  250. bot y8r=0; x8=x2; y9=good.y(y8l+7/6beak)+eps;
  251. arm(8,9,hh,beak_darkness,1.5beak_jut);  % lower arm and beak
  252. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  253.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  254. math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8,9);
  255. uc_hachek_accent(if serifs: 0.4[x1l,x.e1] else: .5 [x1l,x4] fi);
  256. endchar;
  257.  
  258.  
  259. ecchar "The letter E with ogonek"; % from pl_dl (plfonts)
  260. beginchar(oct"206",12u#-width_adj#,cap_height#,the_ogonek_depth#);
  261.  italcorr cap_height#*slant-beak_jut#-.5u#;
  262.  adjust_fit(cap_serif_fit#,0);
  263.  h:=vround(h-stem_corr);
  264.  pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  265.  lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  266.  filldraw stroke z1e--z2e; % stem
  267.  pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  268.  top y3r=h; x3=x1; rt x4r=hround(w-u); y4=good.y(y3l-beak)-eps;
  269.  arm(3,4,e,beak_darkness,beak_jut); % upper arm and beak
  270.  pos5(cap_bar,-90); pos6(hair,0);
  271.  top y5l=vround(.52[y2,y1]+.5cap_bar); x5=x1;
  272.  pos0(cap_bar,90); pos7(hair,0);
  273.  z0=z5; x6=x7; y6-y5l=y0l-y7;
  274.  if serifs: rt x6r=hround(w-4.4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  275.   rt x9r=hround(w-.5u);
  276.  else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  277.  arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0); % middle arm and serif
  278.  pos8(slab if not serifs:+2stem_corr fi,-90); pos9(hair,0);
  279.  bot y8r=0; x8=x2; y9=good.y(y8l+7/6beak)+eps;
  280.  arm(8,9,h,beak_darkness,1.5beak_jut); % lower arm and beak
  281.  if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
  282.   nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi % lower serif
  283.  penlabels(0,1,2,3,4,5,6,7,8,9);
  284.  def the_pen=if known ogonek_pen: ogonek_pen
  285.   elseif serifs: tiny elseif is_bold: fisp else: fine fi
  286.  enddef;
  287.  ogonek_breadth=if serifs and is_bold: slab else: xvair fi;
  288.  ogonek_pos=
  289.   (x.h0-if serifs: 2 else: if is_bold: 1.5 else: 1.75 fi\\ fi\\ u,.5the_pen)+
  290.   .5 ogonek_breadth*if is_egyptian: origin elseif serifs: right else: left fi;
  291.  put_ogonek(the_pen);
  292. endchar;
  293.  
  294. ecchar "The letter G with breve";
  295. if serifs: beginchar(oct"207",14u#,cap_height#+acc_height#,0);
  296.  italcorr cap_height#*slant-1.5u#-.5cap_serif_fit#;
  297.  adjust_fit(0,.5cap_serif_fit#);
  298.  pickup tiny.nib; pos0(cap_stem,0); pos7(cap_stem,0);
  299.  rt x0r=hround(w-2u); y0=good.y(.1[bar_height,x_height]+1); x7=x0;
  300.  pickup fine.nib;
  301.  if hefty: bot y7=0; pos5(cap_stem,0); x5=x0; top y5=tiny.top y0;
  302.  else: pos5(cap_hair,0); pos8(cap_stem,0);
  303.   y7=.5bar_height; z5l=z8l; z8=z7; x9=x8r; bot y9=0;
  304.   filldraw z8l{down}..{4(x9-x8),y9-y8}z9--z8r--cycle; fi % spur
  305.  pos1(cap_hair,0); pos2(cap_band,90);
  306.  pos3(cap_curve,180); pos4(cap_band,270);
  307.  rt x1r=hround(w-2u); lft x3r=hround u; x2=x4=.55[x3,x1];
  308.  top y2r=cap_height+o; bot y4r=-o; y3=.5[y2,y4];
  309.  bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
  310.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  311.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  312.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  313.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...z5e{up}; % arc
  314.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=cap_height+o;
  315.  x1r-x1'=2cap_curve-fine; y1'=y1;
  316.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  317.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  318.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  319.  pickup tiny.nib; filldraw stroke z0e--z7e;  % stem
  320.  dish_serif(0,7,a,1/3,max(cap_jut,2.25u),b,1/3,1.25u);  % serif
  321.  math_fit(-.3cap_height#*slant-.5u#,ic#);
  322. else: beginchar(oct"207",12u#,cap_height#+acc_height#,0);
  323.  italcorr cap_height#*slant-.5u#;
  324.  adjust_fit(0,0);
  325.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  326.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,270);
  327.  rt x1r=hround(w-1.35u); x2=x4=.5w+u;
  328.  lft x3r=hround max(u,2u-.5cap_curve); rt x5l=hround(w-1.2u);
  329.  top y1r=vround .93cap_height+o; top y2r=cap_height+o; y3=.5cap_height;
  330.  bot y4r=-o; bot y5r=vround .07cap_height-o;
  331.  filldraw stroke rterm.e(2,1,right,.9,4)&super_arc.e(2,3)
  332.   & super_arc.e(3,4) & term.e(4,5,right,1,4); % arc and terminals
  333.  pos0(stem,0); pos7(stem,0);
  334.  z7r=z5r; x0=x7; top y0=1+vround .35[bar_height,x_height];
  335.  filldraw stroke z0e--z7e;  % stem
  336.  pos8(cap_bar,90); pos9(cap_bar,90);
  337.  z0r=z9r; y8=y9; lft x8=hround x4;
  338.  filldraw stroke z8e--z9e;  % bar
  339.  math_fit(-.3cap_height#*slant-.5u#,.5ic#); fi
  340. % the accent
  341. uppercase_breve(x2,0,10,11,12);
  342. penlabels(0,1,1',2,3,4,5,6,7,8,9,10,11,12);endchar;
  343.  
  344.  
  345. ecchar "The letter L with acute";
  346. beginchar_twice(oct"210",11u#-width_adj#,cap_height#+acc_height#,0);
  347. adjust_fit(cap_serif_fit#,0);
  348. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  349. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=cap_height; bot y2=0;
  350. filldraw stroke z1e--z2e; % stem
  351. pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
  352. bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
  353. arm(3,4,e,1.2beak_darkness,beak_jut);  % lower arm and beak
  354. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut);  % upper serif
  355.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  356. % the accent
  357. hpos_corr=-.5w+hround max(2u,3u-.5cap_stem);
  358. put_accent;
  359. repeat_once;
  360. math_fit(0,u#); penlabels(1,2,3,4); endchar;
  361.  
  362.  
  363. ecchar "The letter L with hachek"; % from csotheru.mf (csfonts)
  364. beginchar(oct"211",11u#-width_adj#,cap_height#+acc_height#,0);
  365. adjust_fit(cap_serif_fit#,0);
  366. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  367. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=cap_height; bot y2=0;
  368. filldraw stroke z1e--z2e; % stem
  369. pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
  370. bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
  371. arm(3,4,e,1.2beak_darkness,beak_jut);  % lower arm and beak
  372. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut);  % upper serif
  373.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  374. math_fit(0,u#); penlabels(1,2,3,4);
  375. dtl_hachek(x4-pdot_diam)(y1+.5pdot_diam);
  376. endchar;
  377.  
  378. ecchar "The letter crossed L"; % from pl_dl (plfonts)
  379. beginchar_twice(oct"212",11u#-width_adj#,cap_height#,0);
  380.  adjust_fit(cap_serif_fit# if not serifs: +1.5u# fi,0);
  381.  pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  382.  lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  383.  filldraw stroke z1e--z2e; % stem
  384.  pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
  385.  bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
  386.  arm(3,4,e,1.2beak_darkness,beak_jut); % lower arm and beak
  387.  if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut); % upper serif
  388.   nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi % lower serif
  389.  penlabels(1,2,3,4);
  390. % some funny fonts have an extremally small |cap_jut|:
  391.  put_cross(.5cap_stem+if serifs: .9max(limit_dist,cap_jut) else: 1.8u fi,
  392.   .5cap_stem+3u);
  393. repeat_once;
  394. endchar;
  395.  
  396. ecchar "The letter N with acute"; % from pl_dl (plfonts)
  397. beginchar_twice(oct"213",13u#+width_adj#,cap_height#,0);
  398.  italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  399.  adjust_fit(cap_serif_fit#,cap_serif_fit#);
  400.  numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
  401.  pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
  402.  pos3(thin_stem,0); pos4(thin_stem,0);
  403.  pickup tiny.nib; top y1=top y3=h; bot y2=bot y4=0;
  404.  x1=x2; x3=x4; x1l=w-x3r;
  405.  rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
  406.  filldraw stroke z1e--z2e; % left stem
  407.  filldraw stroke z3e--z4e; % right stem
  408.  if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
  409.   x5l=x1; x6r=x4; y5=h; y6=0;
  410.   numeric upper_notch,lower_notch;
  411.   upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
  412.   x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
  413.   fill z5l..
  414.    if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  415.    {z6-z5}diag_in(5l,6l,1,6r)--z6r..
  416.    if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
  417.    {z5-z6}diag_in(6r,5r,1,5l)--cycle; % diagonal
  418.  else: penpos5(whatever,0); penpos6(whatever,90);
  419.   z5l=z1l; z6l=z4l;
  420.   z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
  421.   z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
  422.   filldraw stroke z5e..z6e; fi % diagonal
  423.  if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
  424.   else: serif(5,6,a,1/3,-cap_jut); fi % upper left serif
  425.   dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
  426.   dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi % upper right serif
  427.  penlabels(1,1',2,3,4,4',5,6,7);
  428.  hpos_corr=-.75u; put_accent;
  429. repeat_once;
  430. endchar;
  431.  
  432. ecchar "The letter N with hachek"; % from cshacheu.mf (csfonts)
  433. beginchar(oct"214",13u#+width_adj#,cap_height#+acc_height#,0);
  434. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  435. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  436. numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
  437. pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
  438. pos3(thin_stem,0); pos4(thin_stem,0);
  439. pickup tiny.nib; top y1=top y3=cap_height; bot y2=bot y4=0;
  440. x1=x2; x3=x4; x1l=w-x3r;
  441. rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
  442. filldraw stroke z1e--z2e; % left stem
  443. filldraw stroke z3e--z4e; % right stem
  444. if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
  445.  x5l=x1; x6r=x4; y5=cap_height; y6=0;
  446.  numeric upper_notch,lower_notch;
  447.  upper_notch=cap_height-cap_notch_cut; lower_notch=cap_notch_cut;
  448.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
  449.  fill z5l..
  450.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  451.   {z6-z5}diag_in(5l,6l,1,6r)--z6r..
  452.   if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
  453.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  % diagonal
  454. else: penpos5(whatever,0); penpos6(whatever,90);
  455.  z5l=z1l; z6l=z4l;
  456.  z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
  457.  z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
  458.  filldraw stroke z5e..z6e; fi  % diagonal
  459. if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
  460.  else: serif(5,6,a,1/3,-cap_jut); fi  % upper left serif
  461.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
  462.  dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi  % upper right serif
  463. math_fit(0,max(.5ic#-.5u#,0)); penlabels(1,1',2,3,4,4',5,6,7); 
  464. uc_hachek_accent(.5[x2,x3]);
  465. endchar;
  466.  
  467.  
  468. ecchar "The letter Eng"; % from uppern.mf (fc fonts)
  469. beginchar(oct"215",14u#,cap_height#,0);
  470. adjust_fit(cap_serif_fit#,0);
  471. italcorr cap_height#*slant;
  472. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  473. y1=2/3h; rt x1r=hround(w-u); x2=x1; y2=.21h;
  474. if serifs: pos3(vair,-90); pos4(cap_hair,-180);
  475.  pos5(flare+(cap_stem-stem),-180);
  476.  bot y3r=-o; x3=.5[x4,x2]; y5=1/6h; rt x5l=hround 8.75u; z5r=z4r;
  477.  filldraw stroke z1e--z2e&super_arc.e(2,3);  % right stem and arc
  478.  bulb(3,4,5);  % bulb
  479. else: filldraw stroke z1e--z2e;  % right stem
  480.  pickup fine.nib; pos3(cap_stem,0); z3=z2;
  481.  pos4(flare,angle(6.5u,-h)); pos5(1.1flare,-100);
  482.  bot y4r=-o; x4r=.5[x5r,x3r]; lft x5r=hround 7.75u; bot y5r=vround.06h-o;
  483.  filldraw stroke z3e{down}....term.e(4,5,left,1,4); fi % arc and terminal
  484. pickup tiny.nib; pos6(cap_stem,0);pos7(cap_stem,0);
  485. lft x6l=lft x7l=hround(max(2u,3u-.5cap_stem));top y6=h; bot y7=0;
  486. filldraw stroke z6e--z7e;     %left stem 
  487. pos8(min (cap_hair,cap_stem),0); pos9(cap_hair,-90); pos10(cap_stem,-180);
  488. y8=y10=2/3h; top y9=h+o; rt x8=rt x6; rt x10l=rt x1r; x9=.5[x8,x10];
  489. filldraw stroke z8e{up}...z9e...{down}z10e;  % big arc
  490. if serifs:
  491.   numeric right_jut;              
  492.   if rt x7r+cap_jut+u+1<lft x4r: right_jut=cap_jut;
  493.   else: x7r+right_jut+u+1=lft x4r; fi
  494.   dish_serif(6,7,a,1/3,cap_jut,b,1/3,0);         % upper serif
  495.   dish_serif(7,6,c,1/3,cap_jut,d,1/3,right_jut); % lower serif
  496. fi
  497. math_fit(0,.5ic#-.5u#); penlabels(1,2,3,4,5); endchar;
  498.  
  499. ecchar "The letter O with double acute";
  500. beginchar_twice(oct"216",14u#-width_adj#,cap_height#+acc_height#,0);
  501. italcorr .7cap_height#*slant-.5u#;
  502. adjust_fit(0,0);
  503. penpos1(vair',90); penpos3(vround(vair+1.5vair_corr),-90);
  504. penpos2(cap_curve,180); penpos4(cap_curve,0);
  505. if monospace: x2r=hround 1.5u;
  506.  interim superness:=sqrt superness;  % make |"O"|, not |"0"|
  507. else: x2r=hround u; fi
  508. x4r=w-x2r; x1=x3=.5w; y1r=cap_height+o; y3r=-o;
  509. y2=y4=.5cap_height-vair_corr; y2l:=y4l:=.52cap_height;
  510. penstroke pulled_super_arc.e(1,2)(.5superpull)
  511.  & pulled_super_arc.e(2,3)(.5superpull)
  512.  & pulled_super_arc.e(3,4)(.5superpull)
  513.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  % bowl
  514. math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#);
  515. if monospace: hpos_corr=-2.5u; put_accent; hpos_corr=2.5u; put_accent;
  516. else: hpos_corr=-1.5u; put_accent; hpos_corr=1.5u; put_accent; fi
  517. repeat_once;
  518. penlabels(1,2,3,4); endchar;
  519.  
  520.  
  521. ecchar "The letter R with acute";
  522. beginchar_twice(oct"217",if serifs: 12u#+.5max(2u#,cap_curve#)
  523.  else:12.5u#-.5width_adj# fi,cap_height#+acc_height#,0);
  524. italcorr .75cap_height#*slant- if serifs: 1.75 else: .5 fi\\ u#;
  525. adjust_fit(cap_serif_fit#,0);
  526. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  527. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=cap_height; bot y2=0;
  528. filldraw stroke z1e--z2e; % stem
  529. penpos3(cap_band,90); penpos4(cap_band,90);
  530. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  531. penpos6(vair,-90); penpos7(vair,-90);
  532. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  533. x7=x2; y7l=vround(.5cap_height+.5vair); x4=x6;
  534. if serifs: x4=.5w-.5u; x5r=hround(w-2.25u);
  535. else: x4=.5w+.5u; x5r=hround(w-u); fi
  536. x4l:=x6l:=x4-.125cap_curve;
  537. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  538. if serifs: pos6'(vair,-90); pos0(cap_stem,180);
  539.  pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
  540.  z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
  541.  y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
  542.  bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
  543.  filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up};  % tail
  544.  nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  545.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  % lower serif
  546. else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
  547.  x8=x6+.5u; y8=y6; x9r=hround(w-.5u); y9=0;
  548.  fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi  % tail
  549. hpos_corr=-.75u;
  550. put_accent;
  551. repeat_once;
  552. math_fit(0,.75ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  553.  
  554. ecchar "The letter R with hachek"; % from cshacheu.mf (csfonts)
  555. beginchar(oct"220",if serifs: 12u#+.5max(2u#,cap_curve#)
  556.  else:12.5u#-.5width_adj# fi,cap_height#+acc_height#,0);
  557. italcorr .75cap_height#*slant- if serifs: 1.75 else: .5 fi\\ u#;
  558. adjust_fit(cap_serif_fit#,0);
  559. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  560. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=cap_height; bot y2=0;
  561. filldraw stroke z1e--z2e; % stem
  562. penpos3(cap_band,90); penpos4(cap_band,90);
  563. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  564. penpos6(vair,-90); penpos7(vair,-90);
  565. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  566. x7=x2; y7l=vround(.5cap_height+.5vair); x4=x6;
  567. if serifs: x4=.5w-.5u; x5r=hround(w-2.25u);
  568. else: x4=.5w+.5u; x5r=hround(w-u); fi
  569. x4l:=x6l:=x4-.125cap_curve;
  570. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  571. if serifs: pos6'(vair,-90); pos0(cap_stem,180);
  572.  pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
  573.  z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
  574.  y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
  575.  bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
  576.  filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up};  % tail
  577.  nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  578.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  % lower serif
  579. else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
  580.  x8=x6+.5u; y8=y6; x9r=hround(w-.5u); y9=0;
  581.  fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi  % tail
  582. math_fit(0,.75ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); 
  583. uc_hachek_accent(.9[x1,x6l]);      %(1/3[x1l,x5r]); oprava 24.10.92
  584. endchar;
  585.  
  586.  
  587. ecchar "The letter S with acute"; % from pl_dl (plfonts)
  588. beginchar_twice(oct"221",10u#,cap_height#,0);
  589.  italcorr cap_height#*slant-u#;
  590.  adjust_fit(0,0);
  591.  numeric theta; theta=90-angle(50u,h); slope:=-h/50u; % angle at middle
  592.  numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
  593.  numeric ess'; ess'=max(fine.breadth,cap_ess);
  594.  pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-90);
  595.  pos0(ess',theta); pos7(s_slab,-90);
  596.  x2+x7=2x0=w; x7-x2=if serifs: u else: 0 fi; top y2l=h+o; bot y7r=-o;
  597.  y0=.52h; lft x3l=hround u; rt x6r=hround(w-u);
  598.  x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
  599.  ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  600.  ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  601.  filldraw stroke super_arc.e(2,3) & z3e{down}
  602.   ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
  603.  if serifs: pos1(hair,180); pos8(hair,180);
  604.   rt x1l=hround(w-1.5u); lft x8r=hround u;
  605.   bot y1=vround 2/3h+1; top y8=vround 1/3h-1;
  606.   filldraw stroke z1e{x2-x1,10(y2-y1)}....{left}z2e; % upper arc
  607.   filldraw stroke z7e{left}....{up}z8e; % lower arc
  608.   path upper_arc, lower_arc;
  609.   upper_arc=z1{x2-x1,10(y2-y1)}....{left}z2;
  610.   lower_arc=z7{left}....{up}z8;
  611.   pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
  612.   x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
  613.   x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
  614.   numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
  615.   filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle; % upper barb
  616.   t:=xpart(lower_arc intersectiontimes(z9r--z8'));
  617.   filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle; % lower barb
  618.  else: pos1(1.2flare,-100); pos8(1.2flare,-100);
  619.   x1l=good.x(x1l+w-1.75u-rt x1); lft x8r=hround .8u;
  620.   top y1l=vround .93h+o; bot y8r=vround .1h-o;
  621.   filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
  622.   filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
  623.  penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10);
  624.  hpos_corr=-u; put_accent;
  625. repeat_once;
  626. endchar;
  627.  
  628. ecchar "The letter S with hachek"; % from cshacheu.mf (csfonts)
  629. beginchar(oct"222",10u#,cap_height#+acc_height#,0);
  630. italcorr cap_height#*slant-u#;
  631. adjust_fit(0,0);
  632. numeric theta; theta=90-angle(50u,cap_height);
  633. slope:=-cap_height/50u;  % angle at middle
  634. numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
  635. numeric ess'; ess'=max(fine.breadth,cap_ess);
  636. pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-90);
  637. pos0(ess',theta); pos7(s_slab,-90);
  638. x2+x7=2x0=w; x7-x2=if serifs: u else: 0 fi;
  639. top y2l=cap_height+o; bot y7r=-o;
  640. y0=.52cap_height; lft x3l=hround u; rt x6r=hround(w-u);
  641. x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
  642. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  643. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  644. filldraw stroke super_arc.e(2,3) & z3e{down}
  645.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  646. if serifs: pos1(hair,180); pos8(hair,180);
  647.  rt x1l=hround(w-1.5u); lft x8r=hround u;
  648.  bot y1=vround 2/3cap_height+1; top y8=vround 1/3cap_height-1;
  649.  filldraw stroke z1e{x2-x1,10(y2-y1)}....{left}z2e;  % upper arc
  650.  filldraw stroke z7e{left}....{up}z8e;  % lower arc
  651.  path upper_arc, lower_arc;
  652.  upper_arc=z1{x2-x1,10(y2-y1)}....{left}z2;
  653.  lower_arc=z7{left}....{up}z8;
  654.  pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
  655.  x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
  656.  x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
  657.  numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
  658.  filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle;  % upper barb
  659.  t:=xpart(lower_arc intersectiontimes(z9r--z8'));
  660.  filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle;  % lower barb
  661. else: pos1(1.2flare,-100); pos8(1.2flare,-100);
  662.  x1l=good.x(x1l+w-1.75u-rt x1); lft x8r=hround .8u;
  663.  top y1l=vround .93cap_height+o; bot y8r=vround .1cap_height-o;
  664.  filldraw stroke term.e(2,1,right,.9,4);  % upper arc and terminal
  665.  filldraw stroke term.e(7,8,left,1,4); fi  % lower arc and terminal
  666. math_fit(0,.5ic#); penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10); 
  667. uc_hachek_accent(x0);   %(0.5[x3l,x1l]); oprava 24.10.92
  668. endchar;
  669.  
  670. ecchar "The letter cedilla S";
  671. beginchar(oct"223",10u#,cap_height#,0.875desc_depth#);
  672. italcorr cap_height#*slant-u#;
  673. adjust_fit(0,0);
  674. numeric theta; theta=90-angle(50u,cap_height);
  675. slope:=-cap_height/50u;  % angle at middle
  676. numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
  677. numeric ess'; ess'=max(fine.breadth,cap_ess);
  678. pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-90);
  679. pos0(ess',theta); pos7(s_slab,-90);
  680. x2+x7=2x0=w; x7-x2=if serifs: u else: 0 fi;
  681. top y2l=cap_height+o; bot y7r=-o;
  682. y0=.52cap_height; lft x3l=hround u; rt x6r=hround(w-u);
  683. x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
  684. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  685. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  686. filldraw stroke super_arc.e(2,3) & z3e{down}
  687.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  688. if serifs: pos1(hair,180); pos8(hair,180);
  689.  rt x1l=hround(w-1.5u); lft x8r=hround u;
  690.  bot y1=vround 2/3cap_height+1; top y8=vround 1/3cap_height-1;
  691.  filldraw stroke z1e{x2-x1,10(y2-y1)}....{left}z2e;  % upper arc
  692.  filldraw stroke z7e{left}....{up}z8e;  % lower arc
  693.  path upper_arc, lower_arc;
  694.  upper_arc=z1{x2-x1,10(y2-y1)}....{left}z2;
  695.  lower_arc=z7{left}....{up}z8;
  696.  pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
  697.  x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
  698.  x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
  699.  numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
  700.  filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle;  % upper barb
  701.  t:=xpart(lower_arc intersectiontimes(z9r--z8'));
  702.  filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle;  % lower barb
  703. else: pos1(1.2flare,-100); pos8(1.2flare,-100);
  704.  x1l=good.x(x1l+w-1.75u-rt x1); lft x8r=hround .8u;
  705.  top y1l=vround .93cap_height+o; bot y8r=vround .1cap_height-o;
  706.  filldraw stroke term.e(2,1,right,.9,4);  % upper arc and terminal
  707.  filldraw stroke term.e(7,8,left,1,4); fi  % lower arc and terminal
  708. % the accent
  709. uppercase_cedilla(x7,0,11,12,13,14,15);
  710. math_fit(0,.5ic#);
  711. penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10,11,12,13,14,15); endchar;
  712.  
  713.  
  714. ecchar "The letter T with hachek"; % from cshacheu.mf (csfonts)
  715. beginchar(oct"224",13u#-width_adj#,cap_height#+acc_height#,0);
  716. italcorr cap_height#*slant-beak_jut#-.25u#;
  717. adjust_fit(0,0);
  718. h':=h;
  719. h:=vround(cap_height-2stem_corr);
  720. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  721. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  722. filldraw stroke z1e--z2e; % stem
  723. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  724. top y3r=h; x3=x1; rt x4r=hround(w-.65u); y4=good.y(y3l-beak)-eps;
  725. arm(3,4,e,beak_darkness,.7beak_jut);  % right arm and beak
  726. pos5(hair,180); x5=w-x4; y5=y4;
  727. arm(3,5,f,beak_darkness,-.7beak_jut);  % left arm and beak
  728. if serifs: dish_serif(2,1,c,1/3,1.414cap_jut,d,1/3,1.414cap_jut);  % lower serif
  729.  nodish_serif(1,2,a,1/3,.5cap_jut,b,1/3,.5cap_jut); fi  % upper bracketing
  730. h:=h';
  731. math_fit(-.75cap_height#*slant,ic#-2.5u#); penlabels(1,2,3,4,5,6); 
  732. uc_hachek_accent(x1);
  733. endchar;
  734.  
  735. ecchar "The letter cedilla T";
  736. beginchar(oct"225",13u#-width_adj#,cap_height#,0.875desc_depth#);
  737. italcorr cap_height#*slant-beak_jut#-.25u#;
  738. adjust_fit(0,0);
  739. h:=vround(cap_height-2stem_corr);
  740. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  741. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  742. filldraw stroke z1e--z2e; % stem
  743. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  744. top y3r=h; x3=x1; rt x4r=hround(w-.65u); y4=good.y(y3l-beak)-eps;
  745. arm(3,4,e,beak_darkness,.7beak_jut);  % right arm and beak
  746. pos5(hair,180); x5=w-x4; y5=y4;
  747. arm(3,5,f,beak_darkness,-.7beak_jut);  % left arm and beak
  748. if serifs: dish_serif(2,1,c,1/3,1.414cap_jut,d,1/3,1.414cap_jut);  % lower serif
  749.  nodish_serif(1,2,a,1/3,.5cap_jut,b,1/3,.5cap_jut); fi  % upper bracketing
  750. % the accent
  751. uppercase_cedilla(x2,hair,7,8,9,10,11);
  752. math_fit(-.75cap_height#*slant,ic#-2.5u#);
  753. penlabels(1,2,3,4,5,6,7,8,9,10,11); endchar;
  754.  
  755.  
  756. ecchar "The letter U with double acute";
  757. beginchar_twice(oct"226",13u#+.5width_adj#,cap_height#+acc_height#,0);
  758. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  759. if monospace: adjust_fit(cap_serif_fit#-.5u#,cap_serif_fit#-.5u#)
  760. else: adjust_fit(cap_serif_fit#,cap_serif_fit#) fi;
  761. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  762. pos2'(cap_stem,180); z2'=z2;
  763. pos3(cap_band,-90);
  764. pos4(cap_hair,0); pos5(cap_hair,0);
  765. x1=x2; x3=.5[x1,x5]; x4=x5; x1l=w-x5r;
  766. top y1=top y5=cap_height; y2=y4=1/3cap_height; bot y3r=-o;
  767. lft x1l=hround max(2u,3u-.5cap_stem);
  768. filldraw stroke z1e--z2e; % left stem
  769. filldraw stroke pulled_arc.e(2',3)
  770.  & pulled_arc.e(3,4)&z4e--z5e; % arc and right stem
  771. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % left serif
  772.  dish_serif(5,4,c,1/2,cap_jut,d,1/2,cap_jut)(dark); fi  % right serif
  773. math_fit(-cap_serif_fit#-.3cap_height#*slant-min(cap_height#*slant,u#),
  774.  max(.5ic#-.5u#,0));
  775. if monospace: hpos_corr=-2.5u; put_accent; hpos_corr=2.5u; put_accent;
  776. else: hpos_corr=-1.5u; put_accent; hpos_corr=1.5u; put_accent; fi
  777. repeat_once;
  778. penlabels(1,2,3,4,5); endchar;
  779.  
  780. ecchar "The letter U with ring";
  781. beginchar(oct"227",13u#+.5width_adj#,cap_height#+acc_height#,0);
  782. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  783. if monospace: adjust_fit(cap_serif_fit#-.5u#,cap_serif_fit#-.5u#)
  784. else: adjust_fit(cap_serif_fit#,cap_serif_fit#) fi;
  785. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  786. pos2'(cap_stem,180); z2'=z2;
  787. pos3(cap_band,-90);
  788. pos4(cap_hair,0); pos5(cap_hair,0);
  789. x1=x2; x3=.5[x1,x5]; x4=x5; x1l=w-x5r;
  790. top y1=top y5=cap_height; y2=y4=1/3cap_height; bot y3r=-o;
  791. lft x1l=hround max(2u,3u-.5cap_stem);
  792. filldraw stroke z1e--z2e; % left stem
  793. filldraw stroke pulled_arc.e(2',3)
  794.  & pulled_arc.e(3,4)&z4e--z5e; % arc and right stem
  795. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % left serif
  796.  dish_serif(5,4,c,1/2,cap_jut,d,1/2,cap_jut)(dark); fi  % right serif
  797. math_fit(-cap_serif_fit#-.3cap_height#*slant-min(cap_height#*slant,u#),
  798.  max(.5ic#-.5u#,0));
  799. % the accent
  800. uppercase_circle(
  801. if serifs: .5[x.b1,x.c1] else: x3 fi,
  802.            cap_height+if hefty: .5 fi accent_gap,8,9,10,11);
  803. penlabels(1,2,3,4,5,6,7,8,9,10,11); endchar;
  804.  
  805.  
  806. ecchar "The letter umlaut Y";
  807. beginchar(oct"230",13u#,cap_height#+acc_height#,0);
  808. italcorr cap_height#*slant+.45u#;
  809. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  810. numeric left_stem,right_stem,outer_jut,dy,alpha;
  811. left_stem=cap_stem-stem_corr;
  812. right_stem=min(cap_hair if hefty:-2stem_corr fi,left_stem);
  813. outer_jut=.75cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.05u;
  814. x2l=x5l=hround(.5w-.5left_stem); x3r=x5r;
  815. y1=y4=cap_height; y2=y3=y5=.4cap_height;
  816. dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
  817. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  818. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  819. penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
  820. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  821. if y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
  822.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
  823.     --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  824.     ...{down}z0+.5left--cycle; % diagonals and stem
  825. else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
  826.     --diag_end(5r,6r,1,1,6l,5l)--z5l
  827.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi  % diagonals and stem
  828. if serifs: numeric inner_jut; pickup tiny.nib;
  829.  prime_points_inside(1,2); prime_points_inside(4,3); prime_points_inside(6,5);
  830.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  831.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  832.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % upper left serif
  833.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark);  % upper right serif
  834.  dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi  % lower serif
  835. % the accent
  836. uppercase_umlaut(0,0,7,8,9,10);
  837. math_fit(.5u#-cap_height#*slant,ic#-4u#);
  838. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  839.  
  840. ecchar "The letter Z with acute"; % from pl_dl (plfonts)
  841. beginchar_twice(oct"231",11u#,cap_height#,0);
  842.  italcorr cap_height#*slant-.5u#;
  843.  adjust_fit(0,0);
  844.  numeric arm_thickness[\\],z_stem;
  845.  if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
  846.   z_stem=.8[vair,cap_stem];
  847.  else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
  848.   z_stem=.9[vair,cap_stem]; fi
  849.  pickup tiny.nib; x3l=x4l=w-x1r=w-x2r; lft x3l=hround u;
  850.  top y1=h; y2=min(y1,h-2/3arm_thickness1);
  851.  bot y4=0; y3=max(y4,2/3arm_thickness2);
  852.  numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
  853.  penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
  854.  penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
  855.  pair delta; delta=penoffset z3-z2 of currentpen;
  856.  fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
  857.   ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
  858.   ---cycle; % diagonal
  859.  pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
  860.  top y5r=h; x5=x1; lft x6r=hround 1.25u; y6=good.y(y5l-beak)-eps;
  861.  arm(5,6,a,beak_darkness**.8,-.4beak_jut); % upper arm and beak
  862.  pos7(arm_thickness2,-90); pos8(hair,0);
  863.  bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
  864.  arm(7,8,b,beak_darkness**.9,.6beak_jut); % lower arm and beak
  865.  penlabels(1,2,3,4,5,6,7,8);
  866.  hpos_corr=-.5u; put_accent;
  867. repeat_once;
  868. endchar;
  869.  
  870. ecchar "The letter Z with hachek"; % from cshacheu.mf (csfonts)
  871. beginchar(oct"232",11u#,cap_height#+acc_height#,0);
  872. italcorr cap_height#*slant-.5u#;
  873. adjust_fit(0,0);
  874. numeric arm_thickness[],z_stem;
  875. if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
  876.  z_stem=.8[vair,cap_stem];
  877. else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
  878.  z_stem=.9[vair,cap_stem]; fi
  879. pickup tiny.nib; x3l=x4l=w-x1r=w-x2r; lft x3l=hround u;
  880. top y1=cap_height; y2=min(y1,cap_height-2/3arm_thickness1);
  881. bot y4=0; y3=max(y4,2/3arm_thickness2);
  882. numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
  883. penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
  884. penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
  885. pair delta; delta=penoffset z3-z2 of currentpen;
  886. fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
  887.  ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
  888.  ---cycle;  % diagonal
  889. pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
  890. top y5r=cap_height; x5=x1; lft x6r=hround 1.25u; y6=good.y(y5l-beak)-eps;
  891. arm(5,6,a,beak_darkness**.8,-.4beak_jut);  % upper arm and beak
  892. pos7(arm_thickness2,-90); pos8(hair,0);
  893. bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
  894. arm(7,8,b,beak_darkness**.9,.6beak_jut);  % lower arm and beak
  895. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8); 
  896. uc_hachek_accent(1/2[x6,x1]);
  897. endchar;
  898.  
  899.  
  900. ecchar "The letter Z with dot above"; % from pl_dl (plfonts)
  901. beginchar_twice(oct"233",11u#,cap_height#,0);
  902.  italcorr cap_height#*slant-.5u#;
  903.  adjust_fit(0,0);
  904.  numeric arm_thickness[\\],z_stem;
  905.  if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
  906.   z_stem=.8[vair,cap_stem];
  907.  else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
  908.   z_stem=.9[vair,cap_stem]; fi
  909.  pickup tiny.nib; x3l=x4l=w-x1r=w-x2r; lft x3l=hround u;
  910.  top y1=h; y2=min(y1,h-2/3arm_thickness1);
  911.  bot y4=0; y3=max(y4,2/3arm_thickness2);
  912.  numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
  913.  penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
  914.  penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
  915.  pair delta; delta=penoffset z3-z2 of currentpen;
  916.  fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
  917.   ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
  918.   ---cycle; % diagonal
  919.  pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
  920.  top y5r=h; x5=x1; lft x6r=hround 1.25u; y6=good.y(y5l-beak)-eps;
  921.  arm(5,6,a,beak_darkness**.8,-.4beak_jut); % upper arm and beak
  922.  pos7(arm_thickness2,-90); pos8(hair,0);
  923.  bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
  924.  arm(7,8,b,beak_darkness**.9,.6beak_jut); % lower arm and beak
  925.  penlabels(1,2,3,4,5,6,7,8);
  926.  put_dot(tiny,max(dot_size#,cap_curve#));
  927. repeat_once;
  928. endchar;
  929.  
  930. ecchar "The letter IJ";
  931. beginchar(oct"234",
  932.   9u#+max(6u#,4u#+cap_stem#)
  933.   if not serifs: -u# fi,cap_height#,0);
  934. italcorr cap_height#*slant-cap_serif_fit#
  935.  +.75cap_jut#-2.5u#+min(.5cap_stem#,u#);
  936. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  937. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  938. lft x1l=lft x2l=hround(.5(w-9u)-.5cap_stem); top y1=h; bot y2=0;
  939. filldraw stroke z1e--z2e; % stem
  940. if serifs: dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut);  % upper serif
  941.  dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut);  fi % lower serif
  942. % J part
  943. pickup tiny.nib; pos11(cap_stem',0); pos12(cap_stem',0);
  944. top y11=h; rt x11r=hround(w-2u); x12=x11; y12=.21h;
  945. if serifs: pos13(vair,-90); pos14(cap_hair,-180);
  946.  pos15(flare+(cap_stem-stem),-180);
  947.  bot y13r=-o; x13=.5[x14,x12]; y15=1/6h; rt x15l=hround w-9u+2.75u;
  948.  z15r=z14r;
  949.  filldraw stroke z11e--z12e&super_arc.e(12,13);  % stem and arc
  950.  dish_serif(11,12,aa,1/3,1.3cap_jut,bb,1/3,.75cap_jut);  % serif
  951.  pickup tiny.nib; bulb(13,14,15);  % bulb
  952. else: filldraw stroke z11e--z12e;  % stem
  953.  pickup fine.nib; pos13(cap_stem',0); z13=z12;
  954.  pos14(flare,angle(6.5u,-h)); pos15(1.1flare,-100);
  955.  bot y14r=-o;
  956.  x14r=.5[x15r,x13r];
  957.  lft x15r=hround max(6u,4u+cap_stem)-0.25u;% +.75u;
  958.  bot y15r=vround.06h-o;
  959.  filldraw stroke z13e{down}....term.e(14,15,left,1,4); fi % arc and terminal
  960. math_fit(0,.5ic#-.5u#);
  961. penlabels(1,2,3,4,5,11,12,13,14,15); endchar;
  962.  
  963. iff not suppress_i_dot:
  964. ecchar "The letter I with dot";
  965. beginchar_twice(oct"235",max(6u#,4u#+cap_stem#),cap_height#,0);
  966. italcorr cap_height#*slant-.25u#;
  967. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  968. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  969. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=cap_height; bot y2=0;
  970. filldraw stroke z1e--z2e; % stem
  971. if serifs or monospace:
  972.  dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut);  % upper serif
  973.  dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut);  fi % lower serif
  974. if slitex:
  975.  pickup crisp.nib;           % arms based on proportions of uppercase E
  976.  pos3(slab,90); pos4(slab if not serifs:+2stem_corr fi,-90);
  977.  x3=x4=x1; top y3r=h; bot y4r=0;
  978.  pos5(hair,0); pos6(hair,0); % top and bottom right arms
  979.  rt x5r=rt x6r=hround(w-u);
  980.  pos7(hair,180); pos8(hair,180); % top and bottom left arms
  981.  lft x7r=lft x8r=hround(u);
  982.  y5=y7=good.y(y3l-beak)-eps; % beak in case we ever want a beaked serif!
  983.  y6=y8=good.y(y4l+beak)+eps; % watch that this doesn't get too heavy
  984.  arm(3,5,a,darkness,jut); arm(3,7,b,darkness,jut); % top left and right arms
  985.  arm(4,6,c,darkness,jut); arm(4,8,d,darkness,jut); % bottom left and right
  986. fi
  987. put_dot(tiny,max(dot_size#,cap_curve#));
  988. repeat_once;
  989. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  990.  
  991. endinput;
  992.